Geb and Grails – tips, tricks and gotchas

I’ve been getting familiar with Spock and Geb for the last few weeks. Here are some quick notes, links and files that I have compiled from this experience. I’ve gathered them here for my own quick reference.

Geb is Luke Daley’s fantastic new functional testing library based on web driver. To get started with it, you need to read the book of Geb.

Installing Geb and Spock – step by step.

1. Install the plugins

grails install-plugin geb
grails install-plugin spock 0.5- groovy-1.7-SNAPSHOT

2. Add test dependencies for web driver
In grails-app/conf/BuildConfig.groovy , add the following to the dependencies block:

dependencies {
       test 'org.seleniumhq.selenium:selenium-firefox-driver:latest.release'
       test 'org.seleniumhq.selenium:selenium-chrome-driver:latest.release'
       test 'org.seleniumhq.selenium:selenium-ie-driver:latest.release'
       test('org.seleniumhq.selenium:selenium-htmlunit-driver:latest.release') {
               exclude 'xml-apis'
       }
}

Remember to uncomment the mavenCentral repository for this to work.

3. Install Robert Fletcher’s artefact creation patch for Spock.

These files from Robert Fletcher’s blog replace the standard jUnit test cases that ship with grails with Spock specs. This means that when you run commands like ‘grails create-integration-test com.mydomain.is.awesome’, you get a Spock spec instead of a jUnit test.

1. Copy Events.groovy to your scripts directory
2. Call grails install-templates
3. Copy Spec.groovy into src/templates/artifacts

( Note: the create scripts are broken in grails 1.3.4, so either use grails 1.3.3 or the latest trunk build of grails )

Use grails console for Geb

One of the challenges of learning Geb for me was trying to understand the jQuery-like syntax supported by the $() navigators.

A useful trick I found was to use grails console to quickly evaluate the results of my expressions. Once I was confident that the expression was right, I could then copy these into the content node of my page objects.

• Call ‘grails console’ in your application root.
• Call Browser.drive( ) and use println expressions to output your results. I use the following script:

import geb.*
import org.openqa.selenium.firefox.FirefoxDriver

Browser.drive( new FirefoxDriver(), "http://www.grails.org" ){
    go()
   // expression here
}

Testing Ajax Pages

Luke Daley provided the implementation of a waitFor method in the geb-user mailing list.

       def waitFor(Closure condition) {
               waitFor(null, condition)
       }

       def waitFor(Double timeoutSecs, Closure condition) {
               waitFor(timeoutSecs, null, condition)
       }

       def waitFor(Double timeoutSecs, Double intervalSecs, Closure condition) {
               timeoutSecs = timeoutSecs ?: 5
               intervalSecs = intervalSecs ?: 0.5
               def loops = Math.ceil(timeoutSecs / intervalSecs)
               def pass = condition()
               def i = 0
               while (pass == false && i++ < loops) {
                       Thread.sleep((intervalSecs * 1000) as long)
                       pass = condition()
               }
               if (i >= loops) {
                       throw new AssertionError("condition did not pass in $timeoutSecs seconds")
               }
               true
       }

waitFor basically loops until a certain condition is met. In my spock tests, I would call something like:

when: 'I click on search'
    searchButton.click()
then: 'search wait dialog appears'
    waitFor{ loadingDiv.present }
then: 'search wait dialog is gone'
    waitFor{ !loadingDiv.present }
then: 'my results are loaded'
   ...

I added these to a base page I called AjaxPage and have all my pages that use ajax extend from it.

It is important to put divs that are not visible at the beginning of the page load as required:false in page objects. i.e:

content{
    loadingDiv( required: false ){ $( '#loading' ) }
}

Executing JavaScript

Web driver cannot simulate mouse movement events. Web driver also requires all elements that you call to be visible on the page before you can interact with them or it will throw an exception. You can read more about this in the web driver faq.

The solution to this problem is to use the web driver JavascriptExecutor to put the page in the proper stage. I add this helper method to my Specs:

import org.openqa.selenium.JavascriptExecutor
def js( String script ){
     (driver as JavascriptExecutor).executeScript( script )
}

Then, in my tests, I can simply invoke commands like this:

js( ' jQuery( "myHiddenDiv" ).show(); ' )
js( ' return jQuery( "myHiddenDiv" ).isVisible(); ' )

Important: The reason this method is put in my specs instead of the base page object is because the later seems to make the calls non-blocking. I.e, if I put the js definition in my AjaxPage, waitFor{ myDiv.present } run right away instead of waiting for js( ‘ showHiddenDiv() ‘ ) to finish.

Geb Gotchas

Here are a few things that I always seem to keep forgetting:

1. Call go(). You need to call go() when using a driver other than htmlUnit due to a current bug in Geb 0.4. In my spock tests, it looks like this

when:
   to HomePage
   go()

and in the drive closure,

Browser.drive( new FirefoxDriver(), "http://www.fark.com/" ){
     go()
}

2. There are two GebSpecs, make sure you use the one for grails. There is a file called GebSpec in geb.spock.GebSpec and one for grails called grails.plugin.geb.GebSpec. You MUST make sure you have the right package name and have all your functional specs extend grails.plugin.geb.GebSpec or your test won’t run, your wife will leave you and you will leave a life of loneliness and tears.

3. Spock tests are called Specs. If you call then tests, they won’t get picked up in testing.

4. Remember to use require:false in your page objects. If your div is not visible on startup, you must set required to false – see testing Ajax Pages in this post.

I hope you have found this useful. Join the discussion at the geb-user mailing list if you run into any issues or have questions.